10 T:WHAT'S YOUR NAME?
20 A:$NAME
30 GR:CLEAR
40 *CIRCLE
50 GR:PEN RED;GOTO 0,0;TURNTO #X;GO 25
60 C:#X=#X+1
70 J(#X<>360):*CIRCLE
80 *START
90 C:#R=0
100 C:#T=0
110 T:DO YOU WANT TO PLAY HOURS (H), QUARTER HOURS (Q) OR FIVE MINUTES (M)? (TYPE H,Q, OR M)
120 A:
130 M:H,Q,M
140 JM:*HOUR,*QUARTER,*MINUTE
150 JN:*START
160 *HOUR
170 C:#H=?\12
180 C(#H=0):#H=12
190 GR:GOTO 0,0;TURNTO 0;PEN YELLOW;DRAW 20
200 GR:GOTO 0,0;TURNTO #H*30;DRAW 15
210 GR:PEN RED;GOTO 0,0
220 T:
230 T:WHAT TIME IS IT, $NAME? (JUST TYPE THE HOUR)
240 A:
250 M:#H
260 C:#T=#T+1
270 TN:NO, IT'S REALLY #H. GOOD LUCK ON THE NEXT ONE, $NAME.
280 PAN:150
290 UY:*RIGHT
300 GR:GOTO 0,0;TURNTO #H*30;PEN ERASE;DRAW 15
310 J(#T<12):*HOUR
320 GR(#T=12):GOTO 0,0;TURNTO 0;PEN ERASE;DRAW 20
330 J(#T=12):*REPLAY
340 *QUARTER
350 C:#H=?\12
360 C(#H=0):#H=12
370 C:#Q=?\4
380 C:#N=15*#Q
390 GR:GOTO 0,0;TURNTO #H*30;TURN #Q*(15/2);PEN YELLOW;DRAW 15
400 GR:GOTO 0,0;TURNTO #Q*90;DRAW 20
410 GR:PEN RED;GOTO 0,0
420 T:
430 T:WHAT TIME IS IT, $NAME? (USE THE FORM 9:15, 10:30, ETC.)
440 A:
450 M:#H:#N
460 M(#Q=0):#H
470 C:#T=#T+1
480 UY:*RIGHT
490 UN:*ANSWER
500 GR:GOTO 0,0;TURNTO #H*30;TURN #Q*(15/2);PEN ERASE;DRAW 15
510 GR:GOTO 0,0;TURNTO #Q*90;DRAW 20
520 J(#T<12):*QUARTER
530 J(#T=12):*REPLAY
540 *MINUTE
550 C:#H=?\12
560 C(#H=0):#H=12
570 C:#M=?\12
580 C:#N=#M*5
590 GR:GOTO 0,0;TURNTO #H*30;TURN #M*(5/2);PEN YELLOW;DRAW 15
600 GR:GOTO 0,0;TURNTO #M*30;DRAW 20
610 GR:PEN RED;GOTO 0,0
620 T:
630 T:WHAT TIME IS IT, $NAME? (USE THE FORM 5:25, 12:05, ETC.)
640 A:
650 M:#H:#N
660 M(#N=5):#H:05
670 M(#N=0):#H
680 C:#T=#T+1
690 UY:*RIGHT
700 UN:*ANSWER
710 GR:GOTO 0,0;TURNTO #H*30;TURN #M*(5/2);PEN ERASE;DRAW 15
720 GR:GOTO 0,0;TURNTO #M*30;DRAW 20
730 J(#T<12):*MINUTE
740 J(#T=12):*REPLAY
750 *RIGHT
760 T:RIGHT!
770 C:#R=#R+1
780 SO:13
790 PA:15
800 SO:17
810 PA:15
820 SO:20
830 PA:15
840 SO:25
850 PA:30
860 SO:0
870 E:
880 *ANSWER
890 T(#N=0):NO, IT'S #H:00. GOOD LUCK ON THE NEXT ONE, $NAME.
900 PA(#N=0):150
910 E(#N=0):
920 T(#N=5):NO, IT'S #H:05. GOOD LUCK ON THE NEXT ONE, $NAME.
930 T(#N<>5):NO, IT'S #H:#N. GOOD LUCK ON THE NEXT ONE, $NAME.
940 PA:150
950 E:
960 *REPLAY
970 T:VERY GOOD, $NAME. OUT OF 12, YOU GOT #R RIGHT. WANT TO PLAY SOME MORE?
980 A:
990 M:Y,YES
1000 JM:*START
1010 JN:*END
1020 *END
1030 T:GOODBYE, $NAME.
1040 E:

---

Back to previous page